Added modules

modules/postgresql/manifests/repo/apt_postgresql_org.pp

@@ -0,0 +1,30 @@
+# PRIVATE CLASS: do not use directly
+class postgresql::repo::apt_postgresql_org inherits postgresql::repo {
+  if($ensure == 'present' or $ensure == true) {
+    # Here we have tried to replicate the instructions on the PostgreSQL site:
+    #
+    # http://www.postgresql.org/download/linux/debian/
+    #
+    apt::pin { 'apt.postgresql.org':
+      originator => 'apt.postgresql.org',
+      priority   => 500,
+    }->
+    apt::source { 'apt.postgresql.org':
+      location          => 'http://apt.postgresql.org/pub/repos/apt/',
+      release           => "${::lsbdistcodename}-pgdg",
+      repos             => "main ${version}",
+      key               => 'ACCC4CF8',
+      key_source        => 'http://apt.postgresql.org/pub/repos/apt/ACCC4CF8.asc',
+      include_src       => false,
+    }
+
+    Apt::Source['apt.postgresql.org']->Package<|tag == 'postgresql'|>
+  } else {
+    apt::source { 'apt.postgresql.org':
+      ensure => absent,
+    }
+    apt::pin { 'apt.postgresql.org':
+      ensure => absent,
+    }
+  }
+}

modules/postgresql/manifests/repo/yum_postgresql_org.pp

@@ -0,0 +1,38 @@
+# PRIVATE CLASS: do not use directly
+class postgresql::repo::yum_postgresql_org inherits postgresql::repo {
+  $version_parts   = split($version, '[.]')
+  $package_version = "${version_parts[0]}${version_parts[1]}"
+  $gpg_key_path    = "/etc/pki/rpm-gpg/RPM-GPG-KEY-PGDG-${package_version}"
+
+  if ($ensure == 'present' or $ensure == true) {
+    file { $gpg_key_path:
+      source => 'puppet:///modules/postgresql/RPM-GPG-KEY-PGDG',
+      before => Yumrepo['yum.postgresql.org']
+    }
+
+    if($::operatingsystem == 'Fedora') {
+      $label1 = 'fedora'
+      $label2 = $label1
+    } else {
+      $label1 = 'redhat'
+      $label2 = 'rhel'
+    }
+
+    yumrepo { 'yum.postgresql.org':
+      descr    => "PostgreSQL ${version} \$releasever - \$basearch",
+      baseurl  => "http://yum.postgresql.org/${version}/${label1}/${label2}-\$releasever-\$basearch",
+      enabled  => 1,
+      gpgcheck => 1,
+      gpgkey   => "file:///etc/pki/rpm-gpg/RPM-GPG-KEY-PGDG-${package_version}",
+    }
+
+    Yumrepo['yum.postgresql.org'] -> Package<|tag == 'postgresql'|>
+  } else {
+    yumrepo { 'yum.postgresql.org':
+      enabled => absent,
+    }->
+    file { $gpg_key_path:
+      ensure => absent,
+    }
+  }
+}